Sutun Verilerini Tablo Yapma

Sutun Verilerini Tablo Yapma seklinde bir baslik attik fakat konuyla tam uyumlu yahut anlamli oldugunu dusunmuyorum. Uygun baslik bulmakta zorlandigim bir konu oldu.

Istegimiz bir sutundaki verilerin o sutun secilmek kaydi ile istenilen genislikte bir tablo yapilmasi. Ornegin 4`e kadar sayilarimiz olsun ve 2 hucre genislikli bir tablo olmasini isteyelim. 1,2 tablomuzun ilk satirinin verileri 3 ve 4 ise ikinci satirinin verilerini olusturacaktir.

bu anlattigim basit ornegi ornek dosya icin uyguladim, dosyadan inceleyebilirsiniz.

Sutun Verilerini Tablo Yapmakla ilgili kodlarimiz;

Sub satirlari_tabloya_donustur()

Dim satirlar As Long, Sutun As Long
Dim isutun As Range
Dim Dongu As Long
Dim Basla As Worksheet, dondur As Worksheet

    On Error Resume Next
    'satirlari alinacak sutun secilir
    Set isutun = Application.InputBox(Prompt:="Hedef Satirlar icin tek bir sutun seciniz", _
                                    Title:="Satirlari Donustur", Type:=8)
                                  
    'iptal durumu yahut uygunsuz aralik
    If isutun Is Nothing Then Exit Sub
  
    satirlar = Application.InputBox(Prompt:="Tablo Genisligini Giriniz", _
                                        Title:="Satirlari Donustur", Type:=2)
                                   
    'Iptal durumu
    If satirlar = 0 Then Exit Sub
     'Uygunlugundan emin olma
    If satirlar > ActiveSheet.Columns.Count Then
        MsgBox "Cevirmek istediginiz genislik sayisi mumkun olandan fazla"
        Exit Sub
    End If
    
    'Araligi sinirlama
    Sutun = isutun.Column
    Set isutun = Range(isutun(1, 1), Cells(Rows.Count, Sutun).End(xlUp))

    'Yeni Sayfa
    Set Basla = ActiveSheet
    Set dondur = Sheets.Add()
    Basla.Select
    
    'Genislik degerlerinde Dongu yaratma
    For Dongu = isutun(1, 1).Row To Cells(Rows.Count, Sutun).End(xlUp).Row Step satirlar
            Cells(Dongu, Sutun).Resize(satirlar, 1).Copy
            dondur.Cells(Rows.Count, "A").End(xlUp)(2, 1).PasteSpecial Transpose:=True
            Application.CutCopyMode = False
    Next Dongu
    
    On Error GoTo 0

End Sub

Kodlar uzerinde gerekli aciklamalari yaptim, kod uzerinde anlasilamayan bolumler icin yorum yaziniz. Daha onceki konularimizda ustunden gecmedigimiz farkli bir kod olmadigini dusunuyorum, iyi calismalar.

Sutun Verilerini Tablo Yapma

Yazar: mmustafaaslan

2004 yilindan itibaren ozel bir sirketin finans departmaninda calismaktadir. Kendini excel, visual basic kullaniminda gelistirmis olan yazarimiz; Meslegi geregi SAP konusunda ileri derecede bilgilidir.

Bir Cevap Yazın

E-posta hesabınız yayımlanmayacak. Gerekli alanlar * ile işaretlenmişlerdir


9 + 6 =